@echo off
Set _Args=%*
if `%1` neq `` Set "_Args=%_Args:"=""%"
if /i "%UserName%" == "SYSTEM" (Goto GotAdmin) else (reg query "HKLM\SYSTEM\ControlSet001\Control\MiniNT" 1>nul 2>nul&&Goto GotAdmin)
if exist %WinDir%\System32\fltMC.exe fltMC 1>nul 2>nul||mshta VBScript:CreateObject("Shell.Application").ShellExecute("cmd.exe","/c """"%~f0"" %_Args%""",,"runas",1)(Window.Close) 2>nul&&Exit /b

:GotAdmin
Pushd "%CD%"&cd /d "%~dp0"&Title 更多设置&if exist %WinDir%\System32\ureg.dll Mode 37,6 2>nul
if defined CommonProgramW6432 (Set NirCmd=_Green\NirCmd64.exe) else Set NirCmd=_Green\NirCmd.exe
:: Set NirCmd=&if exist "%NirCmd%" for /f %%i in ('%NirCmd% consolewrite ok 2^>nul') do Set "NirCmd=%NirCmd%"
(if /i "%~1" == "h" Goto Begin)&:: 隐藏批处理窗口
if exist "%NirCmd%" "%NirCmd%" exec hide "%~dpnx0" h %* 1>nul 2>nul&&Exit /b
mshta VBScript:CreateObject("WScript.Shell").Run("""%~dpnx0"" h %_Args%",0)(Window.Close) 2>nul&&Exit /b

:Begin
tskill /? 1>nul 2>nul&&Set "KillSGT=tskill SGTool"||if exist "%NirCmd%" (Set "KillSGT="%NirCmd%" killprocess SGTool") else Set "KillSGT=taskkill /f /im SGTool.exe /t"
Set "KillSGT=del /q SGTool.run 1>nul 2>nul&%KillSGT% 1>nul 2>nul"
REM 判断输入参数
if /i "%~2" == "-page=personcenter" Goto 属性
if /i "%~2" == "-page=skincenter" Goto 属性
if /i "%~2" == "属性设置" Goto 属性
if /i "%~2" == "输入法管理器" Goto 输入
if /i "%~2" == "符号大全" Goto 符号
if /i "%~2" == "常用诗词" Goto 常用
if /i "%~2" == "截图工具" Goto 截图
if /i "%~2" == "手写输入" Goto 手写
if /i "%~2" == "语音输入" Goto 语音
if /i "%~2" == "跨屏输入" Goto 跨屏
if /i "%~2" == "点点输入" Goto 点点
if /i "%~2" == "图片表情" Goto 图片
if /i "%~2" == "颜文字" Goto 颜文

:Menu
Color 2f&Set n=0
(if exist 属性设置.lnk echo [ 属性设置 ]&Set /a n+=1
 if exist 输入法管理器.lnk echo [ 输入法管理器 ]&Set /a n+=1
 if exist 符号大全.lnk echo [ 符号大全 ]&Set /a n+=1
 if exist 常用诗词.lnk echo [ 常用诗词 ]&Set /a n+=1
 if exist 截图工具.lnk echo [ 截图工具 ]&Set /a n+=1
 if exist 手写输入.lnk echo [ 手写输入 ]&Set /a n+=1
 if exist 语音输入.lnk echo [ 语音输入 ]&Set /a n+=1
 if exist 跨屏输入.lnk echo [ 跨屏输入 ]&Set /a n+=1
 if exist 点点输入.lnk echo [ 点点输入 ]&Set /a n+=1 
 if exist 图片表情.lnk echo [ 图片表情 ]&Set /a n+=1
 if exist 颜文字.lnk echo [ 颜文字 ] &Set /a n+=1 
) >"%TEMP%\_MoreConf.txt"
if %n% gtr 0 _Green\WSelect "%TEMP%\_MoreConf.txt" "  ☆ 更多设置 ☆  " "Set item=$item" "↓ 选择操作 ↓" /menu /ontop /fixedfont /ps=1 /fs=11 /bg=#555753 /fc=#FFFFFF /hc=#FFFF80 >"%TEMP%\_MoreConf.bat"
Set item=&Call "%TEMP%\_MoreConf.bat"
del /q "%TEMP%\_MoreConf.txt"&del /q "%TEMP%\_MoreConf.bat"
if defined item (Goto %item:~2,2%) else Exit /b

:属性
:: %KillSGT%
@start "" "%~dp0属性设置.lnk" 1>nul 2>nul
Exit /b

:输入
@start "" "%~dp0输入法管理器.lnk" 1>nul 2>nul
Exit /b

:符号
@start "" "%~dp0符号大全.lnk" 1>nul 2>nul
Exit /b

:常用
@start "" "%~dp0常用诗词.lnk" 1>nul 2>nul
Exit /b

:截图
@start "" "%~dp0截图工具.lnk" 1>nul 2>nul
Exit /b

:手写
@start "" "%~dp0手写输入.lnk" 1>nul 2>nul
Exit /b

:语音
@start "" "%~dp0语音输入.lnk" 1>nul 2>nul
Exit /b

:跨屏
@start "" "%~dp0跨屏输入.lnk" 1>nul 2>nul
Exit /b

:点点
@start "" "%~dp0点点输入.lnk" 1>nul 2>nul
Exit /b

:图片
@start "" "%~dp0图片表情.lnk" 1>nul 2>nul
Exit /b

:颜文
@start "" "%~dp0颜文字.lnk" 1>nul 2>nul
Exit /b